Starting and Stopping Quicktime

Date: Thu, 25 Jul 1996 15:51:19 +1000
From: p.farry@cqu.edu.au (Paul Farry)
Subject: Quicktime Starting and Stopping

When dealing with stopping and starting Quicktime on the Macintosh you have not much to worry about QT works very well on there under Director, but when you take your project to windows performance is a little questionable.

The problem I was experiencing was related to Quicktime Stuttering, this had nothing to do with my movies performance or the CD or the Network traffic, it had to do with the ordering of the starttime, stoptime, movierate, and movietime.

So here is the tip I have for you. If you have any comments or suggestions, send them to me (p.farry@cqu.edu.au)

---

on QTSegmentPlay aChannel,startit,stpos,edpos
  --Comments and bugs to (p.farry@cqu.edu.au)
  if voidp(aChannel) then
    Beep 2
  else
    if QTChannel(aChannel) then
      if voidp(startit) then set startit = true
      --If startit isn't defined assume we just want to play the QT.
      if voidp(stpos) then set stpos = 0
      if voidp(edPos) then set edpos = the duration of cast QTCast(aChannel)
      --If the stpos and edpos aren't defined assume complete QTmovie.
      --
      set the starttime of sprite achannel = stpos
      set the stoptime of sprite achannel = edpos
      set the movietime of sprite achannel = stpos
      --The Movietime of a sprite must be <= the starttime !!!
      updatestage
      --The updatestage is Crucial to prevent stutter.
      set the movieRate of sprite achannel = startit
    end if
  end if
end

on QTChannel aChannel
  --Comments and bugs to (p.farry@cqu.edu.au)
  set qt = the castnum of sprite aChannel
  if QT > 0 then
    if the casttype of cast qt = #digitalvideo then
      return true
    else --Not QT/Digital Video
      return false
    end if
  end if
  return false
end

on QTCast aChannel
  --Comments and bugs to (p.farry@cqu.edu.au)
  if QTChannel(aChannel) then
    return the castnum of sprite aChannel
  end if
end

URL: